当前位置：首页 > 系统教程 > Win7教程 > 详细页面

Win7批处理命令：添加“显示|不显示隐藏文件”右键菜单的解决方法

时间：2022-03-18来源：白菜PE作者：佚名

Win7用户都知道，如果要显示隐藏的文件，需在“文件夹选项”的“查看”页的“高级设置”中将“显示隐藏文件及文件夹、驱动器”选中。这个“显示隐藏文件”的操作方式很不方便，能不能将其放到右键菜单中呢？其实这个功能实现起来很简单，就是修改注册表相关项，添加一个右键菜单，那么写个批处理命令就可以实现它！

添加“显示|不显示隐藏文件”右键菜单的批处理文件。源文件如下：

[plain] view plain copy

print?

@echo off
title 安装"不显示|显示隐藏文件"右键菜单
:begin
cls
mode con cols=60 lines=35
echo.
echo ***********“不显示｜显示隐藏文件”右键菜单***********
echo * *
echo * *
echo * 1.安装 *
echo * *
echo * 2.卸载 *
echo * *
echo * 0.退出 *
echo * *
echo * Author:tht QQ:245806497 *
echo * *
echo * Blog:http://blog.csdn.net/tht2009 *
echo * *
echo *******************************************************
echo.
:menu
echo.
set /p select=请选择:
if %select%==0 exit
if %select%==1 goto install
if %select%==2 goto uninstall
echo 选择无效，请从新输入！
goto menu
:install
echo.
set filename=%SystemRoot%\ShowHideFile.vbs
echo 正在安装执行脚本(ShowHideFile.vbs)……
echo Dim WSHShell>%filename%
echo Set WSHShell = WScript.CreateObject("WScript.Shell")>>%filename%
echo if WshShell.RegRead("HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Hidden") = 1 then>>%filename%
echo WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Hidden", "2", "REG_DWORD">>%filename%
echo else WSHShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\Hidden", "1", "REG_DWORD">>%filename%
echo end if>>%filename%
echo WSHShell.SendKeys("{F5}")>>%filename%
echo Set WSHShell=Nothing>>%filename%
echo WScript.Quit(0)>>%filename%
echo.
echo 正在创建右键菜单……
reg add HKEY_CLASSES_ROOT\Directory\Background\shell\show /d "显示/不显示隐藏文件" /f
echo.
echo 正在关联右键菜单……
reg add HKEY_CLASSES_ROOT\Directory\Background\shell\show\command /d "WScript C:\\Windows\\ShowHideFile.vbs" /f
echo.
if exist %filename% echo 安装成功！
goto end
:uninstall
echo.
set filename=%SystemRoot%\ShowHideFile.vbs
if exist %filename% (
echo.
echo 正在删除执行脚本……
del %filename%)
echo.
echo 正在删除注册表中相关项……
reg delete HKEY_CLASSES_ROOT\Directory\Background\shell\show /f
echo.
echo 卸载成功！
:end
echo.
pause
goto begin